#!/bin/csh -f
#
# PATEST - test PANACEA
#

set System = `../manager/system-id`
set BinDir = ../dev/$System/bin
set ERROR  = "NO"
set FAIL   = "NO"
set status = 0

source ../manager/env-$System

if (-e ../dev/$System/include/panace.h) then

   touch test.error

   rm -f patest.debug
   echo `../manager/pwhich pact` >& patest.debug
   echo `../manager/pwhich cc` >>& patest.debug
   echo "BinDir = $BinDir" >>& patest.debug

   echo ""
   echo "PANACEA TEST..."

   echo ""
   echo -n "                    Building PANACEA Test ....."

   pact Cth >& test.error

   if ($status != 0) then
      echo ""
      cat test.error
      echo "                         Can't build PANACEA Test"
      set ERROR = "TRUE"
   else
      echo " DONE"
      echo ""
      echo "                    PANACEA Time History Test ....."
      ${BinDir}/pathts -c 2
      if ($status != 0) then
         echo "                    PANACEA Time History Test ..... FAILED"
         set ERROR = "TRUE"
      else
         echo "                    PANACEA Time History Test ..... PASSED"
      endif
   endif

   rm test.error

# take care of the ABC test
   if (-d abc) then
      cd abc
      abctest
      if ($status != 0) then
         set ERROR = "TRUE"
      endif
      cd ..
   endif

   echo ""
   if ($ERROR == "TRUE") then
      echo ""
      echo "Debug:"
      cat patest.debug
      echo ""
      echo "PANACEA TEST...FAILED"
   else
      echo "PANACEA TEST...PASSED"
   endif

   echo ""
   echo " --------------------------------------------------------"

endif

set xstatus = 0
if ($ERROR == "TRUE") then
   set xstatus = 1
endif

exit($xstatus)

